Custom Adapters

defmodule SferaDoc.TemplateEngine.Adapter do
  @callback parse(body :: String.t()) ::
              {:ok, parsed :: term()} | {:error, term()}

  @callback render(parsed :: term(), assigns :: map()) ::
              {:ok, html :: String.t()} | {:error, term()}
end

defmodule MyApp.EExEngine do
  @behaviour SferaDoc.TemplateEngine.Adapter

  @impl true
  def parse(body) do
    # EEx compiles at parse time
    {:ok, EEx.compile_string(body)}
  end

  @impl true
  def render(compiled, assigns) do
    html = EEx.eval_compiled(compiled, assigns: assigns)
    {:ok, html}
  rescue
    e -> {:error, e}
  end
end

config :sfera_doc, :template_engine,
  adapter: MyApp.EExEngine

defmodule SferaDoc.PdfEngine.Adapter do
  @callback render(html :: String.t(), opts :: keyword()) ::
              {:ok, binary()} | {:error, term()}
end

defmodule MyApp.WkHtmlToPdf do
  @behaviour SferaDoc.PdfEngine.Adapter

  @impl true
  def render(html, _opts) do
    with {:ok, path} <- Temp.path(%{suffix: ".pdf"}),
         :ok <- write_html_and_convert(html, path),
         {:ok, binary} <- File.read(path) do
      {:ok, binary}
    end
  end

  defp write_html_and_convert(html, output_path) do
    input = Temp.path!(%{suffix: ".html"})
    File.write!(input, html)
    case System.cmd("wkhtmltopdf", [input, output_path]) do
      {_, 0} -> :ok
      {reason, _} -> {:error, reason}
    end
  end
end

config :sfera_doc, :pdf_engine,
  adapter: MyApp.WkHtmlToPdf